（解決時にはお一人様1名に500ptお支払します）

こんな感じで良いでしょうか

Option Explicit '変数宣言を強制
Const TARGETFOLDER = "D:\ARCServeBackup" 'ログファイルの格納フォルダ　←★ここを変える。このフォルダ中のログファイルをチェック
Const FILEPREFIX = "Daily Backup Status Report_data_" 'ファイル名のパターン　先頭からこのパターンのファイルを対象とする
Const ForReading = 1, ForWriting = 2, ForAppending = 8 'ファイル操作の定数
Const TITLE = "ARCServeのバックアップ" 'ダイアログのタイトル

'最新のファイルを探す。ファイルの作成日の最も新しいファイルを取得する。
Dim fso, folder, file
Set fso = WScript.CreateObject("Scripting.FileSystemObject") 'ファイル操作のオブジェクトを生成
Set folder = fso.GetFolder(TARGETFOLDER) 'フォルダオブジェクトを作成

Dim prefixLen 'ファイル名のプレフィクスの長さ
Dim lastDate '作成日
Dim lastFile '新いファイル
prefixLen = Len(FILEPREFIX) 'ファイル名のプレフィクスの長さを取得
lastDate = CDate(0) '作成日の初期化
lastFile = "" '新いファイル名の初期化

'フォルダ中のファイルを列挙
For Each file In folder.Files
If Left(file.Name,prefixLen) = FILEPREFIX Then
'ファイル名がプレフィクスに合致している場合
Dim d, f
d = file.DateCreated
f = file.Name
If CDate(lastDate) < CDate(d) Then
'最新のファイルをキープする
lastDate = d
lastFile = f
End If
End If
Next

'ファイルが見つからない場合はエラー
If lastFile = "" Then
MsgBox "ARCServeのバックアップログがありません。", vbExclamation, TITLE 'メッセージを表示
Set fso = Nothing 'オブジェクトの破棄
WScript.Quit '終わり
End If

'ファイルを開いて内容をまるごと取得
Dim strALL 'ファイルの内容
Set file = fso.OpenTextFile( TARGETFOLDER & "\" & lastFile, ForReading ) 'ファイルを開く
strALL = file.ReadAll 'ファイルの内容をまるごと取得
file.Close 'ファイルを閉じる
Set fso = Nothing 'オブジェクトの破棄

If InStr(strALL,"完了") > 0 Then
'完了の文字が含まれていたら成功のメッセージを表示。
MsgBox "バックアップに成功しました" & vbCrLf & vbCrLf & lastFile, vbInformation, TITLE
Else
'完了の文字が含まれていない場合は失敗のメッセージを表示。
MsgBox "バックアップは失敗しました" & vbCrLf & vbCrLf & lastFile, vbCritical, TITLE
End If

丁寧な注釈をありがとうございます。

すいませんが、やっぱり動かしたところ　古い日付のファイル
の内容を参照しています。

すいません、私txtファイルといいましたがcsvファイルでした。

ログファイルの日付ですが、例をあげますと下記のようになります。

・Daily Backup Status Report_data_hostname_2009-05-24-17-37-10.csv

・Daily Backup Status Report_data_hostname_2009-05-25-17-37-10.csv

すみませんが、よろしくお願いします。

なんども自己レスですいません。

ファイルの作成日付を確認していませんでした。

結論からいいますと　ただしく　動きました。

ありがとうございました。

たびたびすいません。注釈で

・ファイル名のプレフィクス
・ファイル名がプレフィクス

とありますが、すいません。概念がわからないです。

ご教示方よろしくお願いします。

フォルダ中に
Daily Backup Status Report_data_ホスト名_2009-05-24-12-00-00.txt
Daily Backup Status Report_data_ホスト名_2009-05-25-12-00-00.txt
Daily Backup Status Report_data_ホスト名_2009-05-26-12-00-00.txt
というファイルが存在した場合、
「Daily Backup Status Report_data_」で始まるファイルをチェック対象としています。
その他のファイルは除外されます。


プレフィックス：接頭語（prefix）
サフィックス：接尾語（suffix）
というんでしょうか。
つまりは文字列の先頭部分（プレフィックス）を判断して前方一致検索をしています。
http://eigonohon.com/muryoeigo/eigokouza-prefix-suffix.html
http://e-words.jp/w/E5898DE696B9E4B880E887B4.html

たびたびすいません。ありがとうございました。m(_ _)m
これで終わります。

たくさんのポイントありがとうございます。
微調整であればしますので、コメントに書いてください。

たびたびすいません。お客様には　今週中には提示しようと思います。
早速なのですが、下記の処理が必要な理由を教えていただけますでしょうか。よろしくお願いします。

Dim prefixLen 'ファイル名のプレフィクスの長さ
Dim lastDate '作成日
Dim lastFile '新いファイル
prefixLen = Len(FILEPREFIX) 'ファイル名のプレフィクスの長さを取得
lastDate = CDate(0) '作成日の初期化
lastFile = "" '新いファイル名の初期化

prefixLen = Len(FILEPREFIX) 'ファイル名のプレフィクスの長さを取得
＃フォルダ中のファイル名を一つ一つチェックしています。
＃その際、列挙したファイル名の先頭から、定数「FILEPREFIX」で設定した文字数分の文字列を切り出し、
＃定数「FILEPREFIX」と合致しているかどうかチェックしています。

lastDate = CDate(0) '作成日の初期化
lastFile = "" '新いファイル名の初期化
＃lastDate = CDate(0)　はなくても良いです。
＃lastFile = ""　はVBScriptの変数はVariant型なので明示的に空文字列をセットして初期化しました。
＃対象ファイルが見つかると「lastFile」にファイル名がセットされます。
＃セットされていない場合は見つからなかったということです。