出来ればエクセルだけで完結させたいのですが、例えば100個のエクセルファイルの　A1セルに入っている値（情報）を一気に抜き出し101目（べつに何個目でもいいですが）のエクセルに抜き出した値（情報）を表示させたいです。　アクセスでもいいですが、一番簡単な方法で抜き出す方法を教えてください。

改造すればいかようにもなると思いますが
範囲が広い場合、Range("A1:D1")などとして転記したほうがいいかもしれません。
http://officetanaka.net/excel/vba/cell/cell09.htm
あと、Debug.Printは削除忘れのデバッグコードなので不要です。

直してみました。
苦手なのにVBAはOKですとか
質問に具体例を書かないのはダメですよ

Public Sub ReadAll()

    'このフォルダ内のファイルを処理（今回はマクロ配置ブックと同じ場所とする）
    Dim baseDir As String
    baseDir = ThisWorkbook.Path + "\"
    
    'このパターンでxlsxもヒットする
    Dim pattern As String
    pattern = baseDir + "*.xls"
    
    Dim fileName As String
    fileName = Dir(pattern)
    
    Dim row As Integer
    row = 1
    
    '結果貼り付け用に新規シート作成
    Dim mySheet As Worksheet
    Set mySheet = Worksheets.Add
    
    Do While (fileName <> "")
        '自分自身以外のファイルの場合
        If (fileName <> ThisWorkbook.Name) Then
        
            'ブックを開いてA1を取得
            Dim wkb As Workbook
            Set wkb = Workbooks.Open(baseDir + fileName)
            Dim wks As Worksheet
            Set wks = wkb.Worksheets(1)
            
            Dim valueA1 As String
            Dim valueC3 As String
            Dim valueF4 As String
            Dim valueG1 As String
            Dim valueH1 As String
            Dim valueI1 As String
            
            valueA1 = wks.Range("A1").value
            valueC3 = wks.Range("C3").value
            valueF4 = wks.Range("F4").value
            valueG1 = wks.Range("G1").value
            valueH1 = wks.Range("H1").value
            valueI1 = wks.Range("I1").value
            
            '結果シートのA列にファイル名、B列以降に取得した値を転記
            mySheet.Cells(row, 1) = fileName
            mySheet.Cells(row, 2) = valueA1
            mySheet.Cells(row, 3) = valueC3
            mySheet.Cells(row, 4) = valueF4
            mySheet.Cells(row, 5) = valueG1
            mySheet.Cells(row, 6) = valueH1
            mySheet.Cells(row, 7) = valueI1
            row = row + 1
            
            Set wks = Nothing
            wkb.Close
            Set wkb = Nothing
            
        
        End If
        fileName = Dir()
    Loop

    mySheet.Cells.EntireColumn.AutoFit
    Set mySheet = Nothing

End Sub