仕様は以下の通りです｡
★：必須
※：できれば

★ﾌｧｲﾙの読み書きはWindows7上で動作すればOK｡その他のOS対応は不要｡
★Excel2010のVBAﾏｸﾛ記述だけで動作が完結すること｡
他のﾂｰﾙを呼び出すとかはNG｡
★対象は ﾊﾞｲﾅﾘﾌｧｲﾙ×1 複数ﾌｧｲﾙとかﾌｫﾙﾀﾞ毎とかは不要｡
★対象ﾌｧｲﾙは､ｼｰﾄの特定箇所にﾌｧｲﾙ名を記載して指定する｡
※そのExcelﾌｧｲﾙが置かれたﾊﾟｽを検出してくれるか､選択用のﾀﾞｲｱﾛｸﾞが出ると便利｡
★ｻﾑﾁｪｯｸ値は32bitのHEX表現で､特定のｼｰﾄに出力される｡
※ﾏｸﾛ実行する毎に次の行へ書き込んでくれると嬉しい｡
★ｻﾑ値の計算ｱﾙｺﾞﾘｽﾞﾑは任意｡
改ざん防止や保安度については考慮しなくてよい｡
★処理速度優先｡ﾌｧｲﾙの中身が同じなら毎回同じｻﾑ値を出す｡
これができれば複雑な演算は不要｡
※最悪､単純加算でもOKだが､ﾃﾞｰﾀを2箇所変更するとｻﾑ値が同じになってもうたとかそういうのが回避されるとちょっとだけ嬉しい｡
★複数のｱﾙｺﾞﾘｽﾞﾑを切り替える機能は不要｡
(どれでやったかわからなくなるので実装禁止)
★対象となるﾌｧｲﾙのｻｲｽﾞは変動あり｡固定長で処理を中断しないこと｡

＜Sheet1 の内容＞

[ｺﾏﾝﾄﾞﾎﾞﾀﾝ]
＜Sheet1 / ｺﾏﾝﾄﾞﾎﾞﾀﾝｸﾘｯｸ時処理＞

' ﾎﾞﾀﾝｸﾘｯｸ時にｼｰﾄに記載したﾌｧｲﾙのﾊｯｼｭ値を取得する
Private Sub CommandButton1_Click()
 Dim strFileName
 strFileName = Range("A1").Value
 Dim strMD5
 strMD5 = GetFileHashMD5(strFileName)
  ' MD5 ﾊｯｼｭ値128bit中32bitを表示する
 Range("B1").Value = Mid(strMD5, 24, 8)
End Sub

＜標準ﾓｼﾞｭｰﾙ＞

Option Explicit

' 指定したﾌｧｲﾙの MD5 ﾊｯｼｭ値を取得する
Function GetFileHashMD5(strFileName)
 Dim md5
 Set md5 = CreateObject("System.Security.Cryptography.MD5CryptoServiceProvider")
 md5.ComputeHash_2 (ReadBinaryFile(strFileName))
 Dim msxml
 Set msxml = CreateObject("MSXML2.DOMDocument")
 Dim el
 Set el = msxml.CreateElement("tmp")
 el.DataType = "bin.hex"
 el.NodeTypedValue = md5.Hash
 GetFileHashMD5 = el.Text
End Function

' 指定したﾌｧｲﾙのﾊﾞｲﾄ配列を取得する
Function ReadBinaryFile(strFileName)
 Const adTypeBinary = 1
 Dim stm
 Set stm = CreateObject("ADODB.Stream")
 stm.Type = adTypeBinary
 stm.Open
 stm.LoadFromFile strFileName
 ReadBinaryFile = stm.Read
End Function

＜実行結果＞

＜参考ｻｲﾄ＞

■ WindowsでSHA1とMD5を調べる
http://d.hatena.ne.jp/papaking_ken/20110224/1298564016

ﾁｪｯｸｻﾑと言えばCRC32なので探し出しましたがｽﾋﾟｰﾄﾞは遅いです｡
たぶんﾗｲﾌﾞﾗﾘ使ったid:cx20さんのにかなうのはないと思います｡

※そのExcelﾌｧｲﾙが置かれたﾊﾟｽを検出してくれるか､選択用のﾀﾞｲｱﾛｸﾞが出ると便利｡
※ﾏｸﾛ実行する毎に次の行へ書き込んでくれると嬉しい｡

この辺実装しました｡
id:cx20さんのと組み合わせていただければ良いかと思います｡

Option Explicit
Const FileNameSheet = "ﾌｧｲﾙ名"
Const FileNameCell = "A1"
Const HashStoreSheet = "ｻﾑ値"
Const HashStoreColumn = "B"

Dim Crc32Table&(255)

' Mainﾏｸﾛを実行する
Sub Main()
 Dim strFileName As String
 strFileName = GetFileName()
 Dim hash
 hash = GetCrc32FromFile(strFileName)
 hash = Hex(hash)
  'hash = GetFileHashMD5(strFileName)
  'hash = Mid(strHash, 24, 8)
 StoreResult hash
End Sub

Function GetFileName()
  ' ｶﾚﾝﾄﾃﾞｨﾚｸﾄﾘをﾌﾞｯｸのあるﾌｫﾙﾀﾞにすることで絶対ﾊﾟｽ･相対ﾊﾟｽどちらでも対応可能にする
  ' 参考： http://www.asahi-net.or.jp/~ef2o-inue/vba_o/sub05_110_140.html
 ChDrive ThisWorkbook.Path
 ChDir ThisWorkbook.Path
  ' 以下三種の取得方法
  ' GetFileName = Sheets(FileNameSheet).Range(FileNameCell).Value ' 特定ｼｰﾄの特定ｾﾙから得る
 GetFileName = Range(FileNameCell).Value ' 現在のｼｰﾄの特定位置のｾﾙから得る
  ' GetFileName = Selection.Value ' 選択中のｾﾙから得る
End Function

Sub StoreResult(strResult)
 Sheets(HashStoreSheet).Cells(Rows.Count, HashStoreColumn).End(xlUp).Item(2).Value = strResult
  ' Rows.Count 行の最大値
  ' Cells(Rows.Count, "B") B列最終行のｾﾙ
  ' End(xlUp) 上方向(xlUp)でﾃﾞｰﾀのある最初のｾﾙ(Ctrl+↑)
  ' 最終行のｾﾙ ＋ Ctrl+↑ ＝ ﾃﾞｰﾀのある最後のｾﾙ
  ' Item(2) その下のｾﾙ(現在位置を(1)として上下に2番の位置)
End Sub

' 以下ｺﾋﾟﾍﾟ
' http://d.hatena.ne.jp/n7shi/20100910/1284112553
' https://code.msdn.microsoft.com/office/VBACRC-32-dad7d087
' Dim I%, J%, R&, R1&等参考
' http://www.atmarkit.co.jp/fdotnet/vb6tonet/vb6tonet30/vb6tonet30_01.html

Private Sub InitCrc32Table()
 Dim I%, J%, R&, R1&
 For I = 0 To 255
 R = I
 For J = 0 To 7
 R1 = R And 1
 R = (R - R1) / 2
 If R < 0 Then R = R - &H80000000
 If R1 Then R = R Xor &HEDB88320
 Next J
 Crc32Table(I) = R
 Next I
End Sub

Public Function GetCrc32FromFile&(Path$)
 Dim R&, I&, B As Byte, FL&
 If Crc32Table(255) = 0 Then InitCrc32Table
 FL = FileLen(Path)
 Open Path For Binary Lock Read As #2
 R = Not 0
 For I = 1 To FL
 Get #2, , B
 R = (Int(R / 256) And &HFFFFFF) Xor Crc32Table((R Xor B) And &HFF)
 Next I
 Close #2
 GetCrc32FromFile = Not R
End Function

ありがとうございました｡